Quantcast

curve fitting and more

Previous Topic Next Topic
 
classic Classic list List threaded Threaded
4 messages Options
Reply | Threaded
Open this post in threaded view
|  
Report Content as Inappropriate

curve fitting and more

fabrice senger-2
hi there,

any idea ? Multi peak finding and multi peak gaussian fitting. Get Max and
FWHM from plot profile ?

Thank you,

Fabrice.

--
ImageJ mailing list: http://imagej.nih.gov/ij/list.html
Reply | Threaded
Open this post in threaded view
|  
Report Content as Inappropriate

Re: curve fitting and more

Herbie
Fabrice,

could you please be a bit more specific: 1D, 2D...

Get max from plot profile can be done by a macro function (see array
functions).

BTW, were my recent comments on DoG helpful?

Regards

Herbie

::::::::::::::::::::::::::::::::::::::::::::
Am 07.02.17 um 19:28 schrieb Fabrice Senger:

> hi there,
>
> any idea ? Multi peak finding and multi peak gaussian fitting. Get Max and
> FWHM from plot profile ?
>
> Thank you,
>
> Fabrice.
>
> --
> ImageJ mailing list: http://imagej.nih.gov/ij/list.html
>

--
ImageJ mailing list: http://imagej.nih.gov/ij/list.html
Reply | Threaded
Open this post in threaded view
|  
Report Content as Inappropriate

Re: curve fitting and more

Straatman, Kees (Dr.)
In reply to this post by fabrice senger-2
Dear Fabrice,

Have a look at the BAR website (https://imagej.net/BAR).

Kees

-----Original Message-----
From: ImageJ Interest Group [mailto:[hidden email]] On Behalf Of Fabrice Senger
Sent: 07 February 2017 18:29
To: [hidden email]
Subject: curve fitting and more

hi there,

any idea ? Multi peak finding and multi peak gaussian fitting. Get Max and FWHM from plot profile ?

Thank you,

Fabrice.

--
ImageJ mailing list: http://imagej.nih.gov/ij/list.html

--
ImageJ mailing list: http://imagej.nih.gov/ij/list.html
Reply | Threaded
Open this post in threaded view
|  
Report Content as Inappropriate

Re: curve fitting and more

fabrice senger-2
Dear all thank for your interest in that topic.

As I allready mentionned I have found some tools and in particular that
nice macro implemented by John Lim :

//Measure FWHM from intensity profile using Gaussian Fitting
//Image must have aspect ratio of one
//Version 1: 8 Mar 2011, John Lim, IMB
//Version 2; 9 Mar 2011, Send FWHM to a table, John Lim, IMB
//Version 3; 11 Mar 2011, Rename the fitting graph, John Lim, IMB

getPixelSize(unit, pixelWidth, pixelHeight);
getDimensions(width, height, channels, slices, frames);

if(pixelWidth!=pixelHeight){
    exit("Please select an image with pixel aspect ratio of one.")
}

id0=getImageID();
//roiManager("Add");

if(selectionType()!=5){
    exit("Support only straight line");
}
getSelectionBounds(a, b, c, d);
line=""+a+" "+b+" "+c+" "+d;
if(channels>1){
    Stack.getPosition(channel, dummy, dummy);
    line="Ch"+channel+" "+a+" "+b+" "+c+" "+d;
}

Y=getProfile();
len=Y.length;

X=newArray(len);
for(i=0;i<len;i++){
    X[i]=i*pixelHeight;
}

Fit.doFit("Gaussian", X, Y);
r2=Fit.rSquared;
if(r2<0.9){
    showMessage("Warming: Poor Fitting",r2);
}
Fit.plot();
if(isOpen("y = a + (b-a)*exp(-(x-c)*(x-c)/(2*d*d))")){
    selectWindow("y = a + (b-a)*exp(-(x-c)*(x-c)/(2*d*d))");
    rename(line);
}
sigma=Fit.p(3);
FWHM=abs(2*sqrt(2*log(2))*sigma);
myTable(line,FWHM,unit);
selectImage(id0);
selectWindow("FWHM");

function myTable(a,b,c){
    title1="FWHM";
    title2="["+title1+"]";
    if (isOpen(title1)){
           print(title2, a+"\t"+b+"\t"+c);
    }
    else{
           run("Table...", "name="+title2+" width=300 height=200");
           print(title2, "\\Headings:Line\tFWHM\tUnit");
           print(title2, a+"\t"+b+"\t"+c);
    }
}

//--
//ImageJ mailing list: http://imagej.nih.gov/ij/list.html


This macro fits a Gaussian to the most prominent peak in a plot profile
graph and returns FWHM.

The purpose of my enquiry was to have your feedback about possible
developements in that field within imageJ.
Indeed I came accross the BAR plugins and the peak finder...(thank you Kees)

So it is indeed possible to find multiple peaks in a profile plot ans it is
possible to do fitting to peaks...what I'm missing is the combination of
both.

Thank you again for your support,

Fabrice.

2017-02-08 9:17 GMT+01:00 Straatman, Kees (Dr.) <[hidden email]>:

> Dear Fabrice,
>
> Have a look at the BAR website (https://imagej.net/BAR).
>
> Kees
>
> -----Original Message-----
> From: ImageJ Interest Group [mailto:[hidden email]] On Behalf Of
> Fabrice Senger
> Sent: 07 February 2017 18:29
> To: [hidden email]
> Subject: curve fitting and more
>
> hi there,
>
> any idea ? Multi peak finding and multi peak gaussian fitting. Get Max and
> FWHM from plot profile ?
>
> Thank you,
>
> Fabrice.
>
> --
> ImageJ mailing list: http://imagej.nih.gov/ij/list.html
>
> --
> ImageJ mailing list: http://imagej.nih.gov/ij/list.html
>

--
ImageJ mailing list: http://imagej.nih.gov/ij/list.html
Loading...