Good day Martín,

here is an ImageJ-macro that hopefully does what you want:

////macro begin

requires("1.51p")

border = 25;

width = 100;

run( "Select All" );

setKeyDown( "alt" );

p = getProfile();

setKeyDown("none");

p = xtrOfDeriv( p, border );

top = p[0];

bottom = p[1];

makeRectangle( 0, top, getWidth(), bottom - top );

p = getProfile();

max = Array.findMaxima( p, 0 );

x1 = max[0];

peak1 = p[x1];

p = zero( p, x1, width );

max = Array.findMaxima( p, 0 );

x2 = max[0];

peak2 = p[x2];

if ( x2 > x1 ) {

left = x1 + width;

right = x2 - width;

} else {

left = x2 + width;

right = x1 - width;

}

makeRectangle( left, top, right - left, bottom - top );

run( "Set Measurements...", "mean modal median redirect=None decimal=3" );

List.setMeasurements;

med = List.getValue( "Median" );

run( "Select None" );

print( (peak2 - med) / (peak1 - med) );

exit();

////macro functions ===============================================

function zero( a, mx, hw ) {

for ( i=mx-hw; i<=mx+hw; i++ ) {

a[i] = 0;

}

return a;

}

function xtrOfDeriv( a, crop ) {

for ( i=1; i<a.length; i++ ) {

a[i-1] = a[i] - a[i-1];

}

a[a.length-1] = 0;

min = Array.findMinima( a, 0 );

a = Array.findMaxima( a, 0 );

a[0] = a[0] + crop;

a[1] = min[0] - crop;

return a;

}

////macro end

There are two parameters that I've set according to your example image

and if all your images look similar, you may stay with these values:

border = 25;

is the width in pixels of a strip that is cut off from the top and the

bottom of the horizontal band in your image

width = 100;

is about the width of the strips of interest

As a base value (the value that is subtracted) I've used the median of a

selection between the strips of interest. You may also consider the mean

or the modal value.

Paste the macro code to an empty Macro-window and run it.

(Plugins >> New >> Macro)

HTH

Herbie

:::::::::::::::::::::::::::::::::::::::::::::::::::::::

Am 23.07.17 um 17:52 schrieb Mart?n Mat?as P?rez Zan?n:

> Hi everyone, I would like to know if anyone can help me with the

> attached images. The first one it's the original, the second one is

> what I have been done. I need to know the brightness or intensity of

> the two strips that you can see in the frame, and the ratio between

> both (right strip/left strip). There is any way to do this

> automatically? Know the highest value of each curve in the plot?

> Right now I'm doing it manually, then subtract the mode value to both

> and after that I do the ratio (R/L). Do you think I'm doing it ok?

> What would you do/change? another way to do it? Thank you so much

> !!!!

>

> PD: I try image<adjust<brightness-contrast<auto ; then

> Process<subtract background and finally analyze<plot profile

> [cid:image002.jpg@01D303AA.275D35A0]

> [cid:image003.jpg@01D303A9.E9AEF4F0]

>

> -- ImageJ mailing list:

http://imagej.nih.gov/ij/list.html--

ImageJ mailing list:

http://imagej.nih.gov/ij/list.html